gzdoom/wadsrc/static/actors/raven/artiegg.txt

// Egg missile --------------------------------------------------------------

ACTOR EggFX : MorphProjectile
{
	Game Heretic
	SpawnID 40
	Radius 8
	Height 8
	Speed 18
	MorphProjectile.PlayerClass "ChickenPlayer"
	MorphProjectile.MonsterClass "Chicken"
	MorphProjectile.MorphStyle MRF_UNDOBYTOMEOFPOWER
	States
	{
	Spawn:
		EGGM ABCDE 4
		Loop
	Death:
		FX01 FFGH 3 Bright
		Stop
	}
}
	

// Morph Ovum ----------------------------------------------------------------

ACTOR ArtiEgg : CustomInventory 30
{
	Game Heretic
	SpawnID 14
	+COUNTITEM
	+FLOATBOB
	+INVENTORY.INVBAR
	+INVENTORY.PICKUPFLASH
	+INVENTORY.FANCYPICKUPSOUND
	Inventory.Icon "ARTIEGGC"
	Inventory.PickupSound "misc/p_pkup"
	Inventory.PickupMessage "$TXT_ARTIEGG"
	Inventory.DefMaxAmount
	States
	{
	Spawn:
		EGGC ABCB 6
		Loop
	Use:
		TNT1 A 0 A_FireCustomMissile("EggFX", -15, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("EggFX", -7.5, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("EggFX", 0, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("EggFX", 7.5, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("EggFX", 15, 0, 0, 0, 1)
		Stop
	}
}
	
// Pork missile --------------------------------------------------------------

ACTOR PorkFX : MorphProjectile
{
	Game Hexen
	SpawnID 40
	Radius 8
	Height 8
	Speed 18
	MorphProjectile.PlayerClass "PigPlayer"
	MorphProjectile.MonsterClass "Pig"
	MorphProjectile.MorphStyle MRF_UNDOBYTOMEOFPOWER|MRF_UNDOBYCHAOSDEVICE
		States
	{
	Spawn:
		PRKM ABCDE 4
		Loop
	Death:
		FHFX IJKL 3 Bright
		Stop
	}
}

// Porkalator ---------------------------------------------------------------

ACTOR ArtiPork : CustomInventory 30
{
	Game Hexen
	SpawnID 14
	+COUNTITEM
	+FLOATBOB
	+INVENTORY.INVBAR
	+INVENTORY.PICKUPFLASH
	+INVENTORY.FANCYPICKUPSOUND
	Inventory.Icon "ARTIPORK"
	Inventory.PickupSound "misc/p_pkup"
	Inventory.PickupMessage "$TXT_ARTIEGG2"
	Inventory.DefMaxAmount
	States
	{
	Spawn:
		PORK ABCDEFGH 6
		Loop
	Use:
		TNT1 A 0 A_FireCustomMissile("PorkFX", -15, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("PorkFX", -7.5, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("PorkFX", 0, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("PorkFX", 7.5, 0, 0, 0, 1)
		TNT1 A 0 A_FireCustomMissile("PorkFX", 15, 0, 0, 0, 1)
		Stop
	}
}