gzdoom-gles/wadsrc/static/actors/doom/doommisc.txt

// The barrel of green goop ------------------------------------------------

ACTOR ExplosiveBarrel
{
	Health 20
	Radius 10
	Height 42
	+SOLID
	+SHOOTABLE
	+NOBLOOD
	+ACTIVATEMCROSS
	+DONTGIB
	+NOICEDEATH
	+OLDRADIUSDMG
	DeathSound "world/barrelx"
	Obituary "$OB_BARREL"
	States
	{
	Spawn:
		BAR1 AB 6
		Loop
	Death:
		BEXP A 5 BRIGHT
		BEXP B 5 BRIGHT A_Scream
		BEXP C 5 BRIGHT
		BEXP D 5 BRIGHT A_Explode
		BEXP E 10 BRIGHT
		TNT1 A 1050 BRIGHT A_BarrelDestroy
		TNT1 A 5 A_Respawn
		Wait
	}
}

// Bullet puff -------------------------------------------------------------

ACTOR BulletPuff
{
	+NOBLOCKMAP
	+NOGRAVITY
	+ALLOWPARTICLES
	+RANDOMIZE
	RenderStyle Translucent
	Alpha 0.5
	VSpeed 1
	Mass 5
	States
	{
	Spawn:
		PUFF A 4 Bright
		PUFF B 4
	Melee:
		PUFF CD 4
		Stop
	}
}
	
// Container for an unused state -------------------------------------------

/* Doom defined the states S_STALAG, S_DEADTORSO, and S_DEADBOTTOM but never
 * actually used them. For compatibility with DeHackEd patches, they still
 * need to be kept around. This actor serves that purpose.
 */

ACTOR DoomUnusedStates
{
	States
	{
	Label1:
		SMT2 A -1
		stop
	Label2:
		PLAY N -1
		stop
		PLAY S -1
		stop
	TNT: // MBF compatibility
		TNT1 A -1
		Loop
	}
}

// MBF Beta emulation items

Actor EvilSceptre : ScoreItem
{
	Inventory.PickupMessage "$BETA_BONUS3"
	States
	{
	Spawn:
		BON3 A 6
		Loop
	}
}

Actor UnholyBible : ScoreItem
{
	Inventory.PickupMessage "$BETA_BONUS4"
	States
	{
	Spawn:
		BON4 A 6
		Loop
	}
}