mirror of
https://github.com/ZDoom/qzdoom-gpl.git
synced 2024-11-16 09:11:17 +00:00
b599eda17d
monsters - Added velocity multiplicators to A_SpawnDebris. - Changed: A_JumpIfNoAmmo should have no effect for CustomInventory items. - Fixed: DECORATE jump commands must set the call state's result to 0 even when they have to return prematurely. - Added obituaries for Strife's and Hexen's monsters. - Converted Strife's Bishop to DECORATE. - Added momx, momy and momz variables to the DECORATE expression evaluator. SVN r404 (trunk)
100 lines
2.1 KiB
Text
100 lines
2.1 KiB
Text
|
|
// Bishop -------------------------------------------------------------------
|
|
|
|
ACTOR StrifeBishop 187
|
|
{
|
|
Game Strife
|
|
ConversationID 64,-1,-1
|
|
Health 500
|
|
Painchance 128
|
|
Speed 8
|
|
Radius 40
|
|
Height 56
|
|
Mass 500
|
|
Monster
|
|
+NOBLOOD
|
|
+NOTDMATCH
|
|
+FLOORCLIP
|
|
+INCOMBAT
|
|
+FIRERESIST
|
|
+NOICEDEATH
|
|
MinMissileChance 150
|
|
MaxDropoffHeight 32
|
|
SeeSound "bishop/sight"
|
|
PainSound "bishop/pain"
|
|
DeathSound "bishop/death"
|
|
ActiveSound "bishop/active"
|
|
DropItem "CrateOfMissiles", 256, 20
|
|
Obituary "$OB_STFBISHOP"
|
|
States
|
|
{
|
|
Spawn:
|
|
MLDR A 10 A_Look
|
|
Loop
|
|
See:
|
|
MLDR AABBCCDD 3 A_Chase
|
|
Loop
|
|
Missile:
|
|
MLDR E 3 A_FaceTarget
|
|
MLDR F 2 Bright A_CustomMissile("BishopMissile", 64, 0, 0, CMF_AIMOFFSET)
|
|
Goto See
|
|
Pain:
|
|
MLDR D 1 A_Pain
|
|
Goto See
|
|
Death:
|
|
MLDR G 3 Bright
|
|
MLDR H 5 Bright A_Scream
|
|
MLDR I 4 Bright A_TossGib
|
|
MLDR J 0 Bright A_AlertMonsters
|
|
MLDR J 4 Bright A_Explode(64,64)
|
|
MLDR KL 3 Bright
|
|
MLDR M 4 Bright A_NoBlocking
|
|
MLDR N 4 Bright
|
|
MLDR O 4 Bright A_TossGib
|
|
MLDR P 4 Bright
|
|
MLDR Q 4 Bright A_TossGib
|
|
MLDR R 4 Bright
|
|
MLDR S 4 Bright A_TossGib
|
|
MLDR T 4 Bright
|
|
MLDR U 4 Bright A_TossGib
|
|
MLDR V 4 Bright A_SpawnItemEx("AlienSpectre2", 0, 0, 0, 0, 0, random[spectrespawn](0,255)*0.0078125, 0, SXF_NOCHECKPOSITION)
|
|
Stop
|
|
}
|
|
}
|
|
|
|
|
|
// The Bishop's missile -----------------------------------------------------
|
|
|
|
ACTOR BishopMissile
|
|
{
|
|
Speed 20
|
|
Radius 10
|
|
Height 14
|
|
Damage 10
|
|
Projectile
|
|
+SEEKERMISSILE
|
|
+STRIFEDAMAGE
|
|
MaxStepHeight 4
|
|
SeeSound "bishop/misl"
|
|
DeathSound "bishop/mislx"
|
|
States
|
|
{
|
|
Spawn:
|
|
MISS A 4 Bright
|
|
MISS B 3 Bright A_Tracer2
|
|
MISS A 0 Bright A_PlaySoundEx("misc/missileinflight", "Voice")
|
|
MISS A 0 Bright A_SpawnItemEx("MiniMissilePuff", 0,0, random2[BishopMissile]()*0.015625)
|
|
MISS A 4 Bright A_SpawnItemEx("RocketTrail", -momx,-momy,0, 0,0,1)
|
|
Goto Spawn+1
|
|
Death:
|
|
SMIS A 0 Bright A_SetTranslucent(1,1)
|
|
SMIS A 0 Bright A_StopSoundEx("Voice")
|
|
SMIS A 0 Bright A_AlertMonsters
|
|
SMIS A 5 Bright A_Explode(64,64)
|
|
SMIS B 5 Bright
|
|
SMIS C 4 Bright
|
|
SMIS DEFG 2 Bright
|
|
Stop
|
|
}
|
|
}
|
|
|