mirror of
https://github.com/ZDoom/gzdoom.git
synced 2024-11-06 04:50:26 +00:00
8c2f651bdb
- After doing some tests with state label scopes I had to conclude that using '.' both for separating sub-state-labels and scope resolution identifiers does not work reliably unless all actor class names were prohibited from being used as state labels. Since that is undesirable the only solution is to change the scope resolution operator. Fortunately no WADs so far have used it so implementing such a breaking change isn't a major issue. Now it uses '::', like C++ for this purpose. - Converted Revenant, Mancubus and Pain Elemental to DECORATE. SVN r375 (trunk)
94 lines
1.5 KiB
Text
94 lines
1.5 KiB
Text
//===========================================================================
|
|
//
|
|
// Mancubus
|
|
//
|
|
//===========================================================================
|
|
ACTOR Fatso 67
|
|
{
|
|
Game Doom
|
|
SpawnID 112
|
|
Health 600
|
|
Radius 48
|
|
Height 64
|
|
Mass 1000
|
|
Speed 8
|
|
PainChance 80
|
|
Monster
|
|
+FLOORCLIP
|
|
+BOSSDEATH
|
|
SeeSound "fatso/sight"
|
|
PainSound "fatso/pain"
|
|
DeathSound "fatso/death"
|
|
ActiveSound "fatso/active"
|
|
AttackSound "fatso/raiseguns"
|
|
Obituary "$OB_FATSO"
|
|
States
|
|
{
|
|
Spawn:
|
|
FATT AB 15 A_Look
|
|
Loop
|
|
See:
|
|
FATT AABBCCDDEEFF 4 A_Chase
|
|
Loop
|
|
Missile:
|
|
FATT G 20 A_FatRaise
|
|
FATT H 10 BRIGHT A_FatAttack1
|
|
FATT IG 5
|
|
FATT H 10 BRIGHT A_FatAttack2
|
|
FATT IG 5
|
|
FATT H 10 BRIGHT A_FatAttack3
|
|
FATT IG 5
|
|
Goto See
|
|
Pain:
|
|
FATT J 3
|
|
FATT J 3 A_Pain
|
|
Goto See
|
|
Death:
|
|
FATT K 6
|
|
FATT L 6 A_Scream
|
|
FATT M 6 A_NoBlocking
|
|
FATT NOPQRS 6
|
|
FATT T -1 A_BossDeath
|
|
Stop
|
|
Raise:
|
|
FATT R 5
|
|
FATT QPONMLK 5
|
|
Goto See
|
|
}
|
|
}
|
|
|
|
|
|
|
|
//===========================================================================
|
|
//
|
|
// Mancubus fireball
|
|
//
|
|
//===========================================================================
|
|
ACTOR FatShot
|
|
{
|
|
Game Doom
|
|
SpawnID 153
|
|
Radius 6
|
|
Height 8
|
|
Speed 20
|
|
Damage 8
|
|
Projectile
|
|
+RANDOMIZE
|
|
RenderStyle Add
|
|
Alpha 1
|
|
SeeSound "fatso/attack"
|
|
DeathSound "fatso/shotx"
|
|
States
|
|
{
|
|
Spawn:
|
|
MANF AB 4 BRIGHT
|
|
Loop
|
|
Death:
|
|
MISL B 8 BRIGHT
|
|
MISL C 6 BRIGHT
|
|
MISL D 4 BRIGHT
|
|
Stop
|
|
}
|
|
}
|
|
|
|
|