gzdoom-gles/wadsrc/static/actors/doom/bossbrain.txt

//===========================================================================
//
// Boss Brain
//
//===========================================================================

ACTOR BossBrain
{
	Health 250
	Mass 10000000
	PainChance 255
	+SOLID +SHOOTABLE
	+NOICEDEATH
	+OLDRADIUSDMG
	PainSound "brain/pain"
	DeathSound "brain/death"
	States
	{
	BrainExplode:
		MISL BC 10 Bright
		MISL D 10 A_BrainExplode
		Stop
	Spawn:
		BBRN A -1
		Stop
	Pain:
		BBRN B 36 A_BrainPain
		Goto Spawn
	Death:
		BBRN A 100 A_BrainScream
		BBRN AA 10
		BBRN A -1 A_BrainDie
		Stop
	}
}


//===========================================================================
//
// Boss Eye
//
//===========================================================================

ACTOR BossEye
{
	Height 32
	+NOBLOCKMAP
	+NOSECTOR
	States
	{
	Spawn:
		SSWV A 10 A_Look
		Loop
	See:
		SSWV A 181 A_BrainAwake
		SSWV A 150 A_BrainSpit
		Wait
	}
}

//===========================================================================
//
// Boss Target
//
//===========================================================================

ACTOR BossTarget : SpecialSpot
{
	Height 32
	+NOBLOCKMAP
	+NOSECTOR
}

//===========================================================================
//
// Spawn shot
//
//===========================================================================

ACTOR SpawnShot
{
	Radius 6
	Height 32
	Speed 10
	Damage 3
	Projectile
	+NOCLIP
	-ACTIVATEPCROSS
	+RANDOMIZE
	SeeSound "brain/spit"
	DeathSound "brain/cubeboom"
	States
	{
	Spawn:
		BOSF A 3 BRIGHT A_SpawnSound
		BOSF BCD 3 BRIGHT A_SpawnFly
		Loop
	}
}
		
//===========================================================================
//
// Spawn fire
//
//===========================================================================

ACTOR SpawnFire
{
	Height 78
	+NOBLOCKMAP
	+NOGRAVITY
	RenderStyle Add
	States
	{
	Spawn:
		FIRE ABCDEFGH 4 Bright A_Fire
		Stop
	}
}