
// The Cleric's Mace --------------------------------------------------------

ACTOR CWeapMace : ClericWeapon
{
	Game Hexen
	Weapon.SelectionOrder 3500
	Weapon.KickBack 150
	Weapon.YAdjust -8
	+BLOODSPLATTER
	Obituary "$OB_MPCWEAPMACE"
	Tag "$TAG_CWEAPMACE"

	action native A_CMaceAttack();

	States
	{
	Select:
		CMCE A 1 A_Raise
		Loop
	Deselect:
		CMCE A 1 A_Lower
		Loop
	Ready:
		CMCE A 1 A_WeaponReady
		Loop
	Fire:
		CMCE B 2 Offset (60, 20)
		CMCE B 1 Offset (30, 33)
		CMCE B 2 Offset (8, 45)
		CMCE C 1 Offset (8, 45)
		CMCE D 1 Offset (8, 45)
		CMCE E 1 Offset (8, 45)
		CMCE E 1 Offset (-11, 58) A_CMaceAttack
		CMCE F 1 Offset (8, 45)
		CMCE F 2 Offset (-8, 74)
		CMCE F 1 Offset (-20, 96)
		CMCE F 8 Offset (-33, 160)
		CMCE A 2 Offset (8, 75) A_ReFire
		CMCE A 1 Offset (8, 65)
		CMCE A 2 Offset (8, 60)
		CMCE A 1 Offset (8, 55)
		CMCE A 2 Offset (8, 50)
		CMCE A 1 Offset (8, 45)
		Goto Ready
	}
}
