//===========================================================================
//
// Commander Keen
//
//===========================================================================
ACTOR CommanderKeen
{
	Health 100
	Radius 16
	Height 72
	Mass 10000000
	PainChance 256
	+SOLID 
	+SPAWNCEILING 
	+NOGRAVITY 
	+SHOOTABLE 
	+COUNTKILL 
	+NOICEDEATH
	+ISMONSTER
	PainSound "keen/pain"
	DeathSound "keen/death"
	States
	{
	Spawn:
		KEEN A   -1
		Loop
	Death:
		KEEN AB	6
		KEEN C	6 A_Scream
		KEEN DEFGH	6
		KEEN I	6
		KEEN J	6
		KEEN K	6 A_KeenDie
		KEEN L   -1
		Stop
	Pain:
		KEEN M	4
		KEEN M	8 A_Pain
		Goto Spawn
	}
}
