mirror of
https://github.com/ZDoom/gzdoom.git
synced 2024-11-30 07:41:22 +00:00
129 lines
2.5 KiB
Text
129 lines
2.5 KiB
Text
|
|
// Crusader -----------------------------------------------------------------
|
|
|
|
ACTOR Crusader 3005
|
|
{
|
|
Game Strife
|
|
ConversationID 63,-1,-1
|
|
Speed 8
|
|
Radius 40
|
|
Height 56
|
|
Mass 400
|
|
Health 400
|
|
Painchance 128
|
|
Monster
|
|
+FLOORCLIP
|
|
+DONTMORPH
|
|
+MISSILEMORE
|
|
+INCOMBAT
|
|
+NOICEDEATH
|
|
+NOBLOOD
|
|
MinMissileChance 120
|
|
MaxDropoffHeight 32
|
|
DropItem "EnergyPod", 256, 20
|
|
SeeSound "crusader/sight"
|
|
PainSound "crusader/pain"
|
|
DeathSound "crusader/death"
|
|
ActiveSound "crusader/active"
|
|
Obituary "$OB_CRUSADER"
|
|
|
|
action native A_CrusaderChoose ();
|
|
action native A_CrusaderSweepLeft ();
|
|
action native A_CrusaderSweepRight ();
|
|
action native A_CrusaderRefire ();
|
|
action native A_CrusaderDeath ();
|
|
|
|
States
|
|
{
|
|
Spawn:
|
|
ROB2 Q 10 A_Look
|
|
Loop
|
|
See:
|
|
ROB2 AABBCCDD 3 A_Chase
|
|
Loop
|
|
Missile:
|
|
ROB2 E 3 A_FaceTarget
|
|
ROB2 F 2 Bright A_CrusaderChoose
|
|
ROB2 E 2 Bright A_CrusaderSweepLeft
|
|
ROB2 F 3 Bright A_CrusaderSweepLeft
|
|
ROB2 E 2 Bright A_CrusaderSweepLeft
|
|
ROB2 F 2 Bright A_CrusaderSweepLeft
|
|
ROB2 E 2 Bright A_CrusaderSweepRight
|
|
ROB2 F 2 Bright A_CrusaderSweepRight
|
|
ROB2 E 2 Bright A_CrusaderSweepRight
|
|
ROB2 F 2 A_CrusaderRefire
|
|
Loop
|
|
Pain:
|
|
ROB2 D 1 A_Pain
|
|
Goto See
|
|
Death:
|
|
ROB2 G 3 A_Scream
|
|
ROB2 H 5 A_TossGib
|
|
ROB2 I 4 Bright A_TossGib
|
|
ROB2 J 4 Bright A_Explode(64,64,1,1)
|
|
ROB2 K 4 Bright A_Fall
|
|
ROB2 L 4 A_Explode(64,64,1,1)
|
|
ROB2 MN 4 A_TossGib
|
|
ROB2 O 4 A_Explode(64,64,1,1)
|
|
ROB2 P -1 A_CrusaderDeath
|
|
Stop
|
|
}
|
|
}
|
|
|
|
|
|
// Fast Flame Projectile (used by Crusader) ---------------------------------
|
|
|
|
ACTOR FastFlameMissile : FlameMissile
|
|
{
|
|
Mass 50
|
|
Damage 1
|
|
Speed 35
|
|
}
|
|
|
|
// Crusader Missile ---------------------------------------------------------
|
|
// This is just like the mini missile the player shoots, except it doesn't
|
|
// explode when it dies, and it does slightly less damage for a direct hit.
|
|
|
|
ACTOR CrusaderMissile
|
|
{
|
|
Speed 20
|
|
Radius 10
|
|
Height 14
|
|
Damage 7
|
|
Projectile
|
|
+STRIFEDAMAGE
|
|
MaxStepHeight 4
|
|
SeeSound "crusader/misl"
|
|
DeathSound "crusader/mislx"
|
|
States
|
|
{
|
|
Spawn:
|
|
MICR A 6 Bright A_RocketInFlight
|
|
Loop
|
|
Death:
|
|
SMIS A 0 Bright A_SetTranslucent(1,1)
|
|
SMIS A 5 Bright A_StopSoundEx("Voice")
|
|
SMIS B 5 Bright
|
|
SMIS C 4 Bright
|
|
SMIS DEFG 2 Bright
|
|
Stop
|
|
}
|
|
}
|
|
|
|
|
|
// Dead Crusader ------------------------------------------------------------
|
|
|
|
ACTOR DeadCrusader 22
|
|
{
|
|
Game Strife
|
|
ConversationID 230
|
|
States
|
|
{
|
|
Spawn:
|
|
ROB2 N 4
|
|
ROB2 O 4
|
|
ROB2 P -1
|
|
Stop
|
|
}
|
|
}
|
|
|