/***
*
*	Copyright (c) 2016-2019 Marco 'eukara' Hladik. All rights reserved.
*
*	See the file LICENSE attached with the sources for usage details.
*
****/

enum
{
	RPG_IDLE,
	RPG_FIDGET,
	RPG_RELOAD,
	RPG_FIRE2,
	RPG_HOLSTER1,
	RPG_DRAW1,
	RPG_HOLSTER2,
	RPG_DRAW_UL,
	RPG_IDLE_UL,
	RPG_FIDGET_UL,
};

void w_rpg_precache(void)
{
	precache_model("models/v_rpg.mdl");
	precache_model("models/w_rpg.mdl");
	precache_model("models/p_rpg.mdl");
	precache_model("models/rpgrocket.mdl");
	precache_model("sprites/laserdot.spr");
	precache_sound("weapons/rocketfire1.wav");
}
string w_rpg_vmodel(void)
{
	return "models/v_rpg.mdl";
}
string w_rpg_wmodel(void)
{
	return "models/w_rpg.mdl";
}
string w_rpg_pmodel(void)
{
	return "models/p_rpg.mdl";
}
string w_rpg_deathmsg(void)
{
	return "";
}

void w_rpg_draw(void)
{
#ifdef CSQC
	Weapons_ViewAnimation(RPG_DRAW1);
#else
	player pl = (player)self;
	Weapons_UpdateAmmo(pl, pl.rpg_mag, pl.ammo_rocket, __NULL__);
#endif
}

void w_rpg_holster(void)
{
	
}
void w_rpg_primary(void)
{
	player pl = (player)self;
	if (pl.w_attack_next > 0.0) {
		return;
	}

#ifdef CSQC
	Weapons_ViewAnimation(RPG_FIRE2);
#else
	static void Rocket_Touch(void) {
		Effect_CreateExplosion(self.origin);
		Damage_Radius(self.origin, self.owner, 150, 150 * 2.5f, TRUE);
		sound(self, CHAN_WEAPON, sprintf( "weapons/explode%d.wav", floor( random() * 2 ) + 3 ), 1, ATTN_NORM);
		remove(self);
	}
	static void Rocket_BuildSpeed(void){
		/* Calculate new direction */
		makevectors(self.owner.v_angle);
		traceline(self.owner.origin, self.owner.origin + v_forward * 8096, FALSE, self.owner);
		self.angles = vectoangles(trace_endpos - self.origin);

		/* Increase speed towards it */
		makevectors(self.angles);
		self.velocity += (v_forward * 2000) * frametime;
		self.nextthink = time;
	}

	Weapons_MakeVectors();
	entity rocket = spawn();
	setmodel(rocket, "models/rpgrocket.mdl");
	setorigin(rocket, Weapons_GetCameraPos() + (v_forward * 16));
	rocket.owner = self;
	rocket.movetype = MOVETYPE_FLY;
	rocket.solid = SOLID_BBOX;
	//bolt.flags |= FL_LAGGEDMOVE;
	rocket.gravity = 0.5f;
	rocket.velocity = (v_forward * 250);
	rocket.angles = vectoangles(rocket.velocity);
	rocket.avelocity[2] = 10;
	rocket.touch = Rocket_Touch;
	rocket.think = Rocket_BuildSpeed;
	rocket.nextthink = time + 0.15f;
	setsize(rocket, [0,0,0], [0,0,0]);
	sound(self, CHAN_WEAPON, "weapons/rocketfire1.wav", 1, ATTN_NORM);
#endif

	pl.w_attack_next = 1.0f;
	pl.w_idle_next = 2.5f;
}
void w_rpg_secondary(void)
{
	
}
void w_rpg_reload(void)
{
	
}
void w_rpg_release(void)
{
	
}

float w_rpg_aimanim(void)
{
#ifdef SSQC
	return self.flags & FL_CROUCHING ? ANIM_CR_AIMRPG : ANIM_AIMRPG;
#endif
}

void w_rpg_hudpic(int s, vector pos)
{
#ifdef CSQC
	if (s) {
		drawsubpic(pos, [170,45], "sprites/640hud5.spr_0.tga", [0,45/256], [170/256,45/256], g_hud_color, 1, DRAWFLAG_ADDITIVE);
	} else {
		drawsubpic(pos, [170,45], "sprites/640hud2.spr_0.tga", [0,45/256], [170/256,45/256], g_hud_color, 1, DRAWFLAG_ADDITIVE);
	}
#endif
}

void w_rpg_laser(void)
{
#ifdef CSQC
	player pl = (player)self;

	Weapons_MakeVectors();
	vector src = pl.origin + pl.view_ofs;
	traceline(src, src + (v_forward * 8192), FALSE, pl);

	/*makevectors(vectoangles(trace_endpos - pl.origin));
	vector forg = trace_endpos + (v_forward * -16);
	vector fsize = [64, 64];
	
	makevectors(view_angles);
	R_BeginPolygon("sprites/640hud7.spr_0.tga", 1, 0);
	R_PolygonVertex(forg + v_right * fsize[0] - v_up * fsize[1], [1,1], [1,1,1], 1.0f);
	R_PolygonVertex(forg - v_right * fsize[0] - v_up * fsize[1], [0,1], [1,1,1], 1.0f);
	R_PolygonVertex(forg - v_right * fsize[0] + v_up * fsize[1], [0,0], [1,1,1], 1.0f);
	R_PolygonVertex(forg + v_right * fsize[0] + v_up * fsize[1], [1,0], [1,1,1], 1.0f);
	R_EndPolygon();*/
	static vector cross_pos;
	vector lasersize = [8,8] * (1-trace_fraction);
	cross_pos = (video_res / 2) - (lasersize/2);
	drawpic(cross_pos, "sprites/laserdot.spr_0.tga", lasersize, [1,1,1], 1.0f, DRAWFLAG_ADDITIVE);
#endif
}

weapon_t w_rpg =
{
	ITEM_RPG,
	3,
	0,
	w_rpg_draw,
	w_rpg_holster,
	w_rpg_primary,
	w_rpg_secondary,
	w_rpg_reload,
	w_rpg_release,
	w_rpg_laser,
	w_rpg_precache,
	__NULL__,
	w_rpg_vmodel,
	w_rpg_wmodel,
	w_rpg_pmodel,
	w_rpg_deathmsg,
	w_rpg_aimanim,
	w_rpg_hudpic
};

#ifdef SSQC
void weapon_rpg(void) {
	Weapons_InitItem(WEAPON_RPG);
}
#endif