apply plugin: 'com.android.application'
apply from: "${rootProject.projectDir}/XrApp.gradle"

android {
  // This is the name of the generated apk file, which will have
  // -debug.apk or -release.apk appended to it.
  // The filename doesn't effect the Android installation process.
  // Use only letters to remain compatible with the package name.
  project.archivesBaseName = "jkxr"

  defaultConfig {
    // Gradle replaces the manifest package with this value, which must
    // be unique on a system.  If you don't change it, a new app
    // will replace an older one.
    applicationId "com.drbeef." + project.archivesBaseName

    // override app plugin abiFilters for both 32 and 64-bit support
      externalNativeBuild {
          ndk {
              abiFilters 'arm64-v8a'
          }
          ndkBuild {
              abiFilters 'arm64-v8a'
          }
      }

      minSdkVersion 26
      targetSdkVersion 26
  }

  sourceSets {
    main {
      manifest.srcFile 'AndroidManifest.xml'
      java.srcDirs = ['../../java']
      jniLibs.srcDir 'libs'
      res.srcDirs = ['../../res']
      assets.srcDirs = ['../../assets']
    }
  }

    packagingOptions {
        exclude 'lib/arm64-v8a/libopenxr_loader.so'
    }

    compileOptions {
        sourceCompatibility = '1.8'
        targetCompatibility = '1.8'
    }
    compileSdkVersion = 26
    buildToolsVersion = '29.0.1'
}

dependencies {
    implementation "com.android.support:support-compat:26.1.0"
    implementation "com.android.support:support-core-utils:26.1.0"
    implementation fileTree(dir: 'libs', include: ['*.jar', '*.aar'])
}

repositories {
    google()
}
buildscript {
    repositories {
        google()
    }
}

task packJOResources(type: Zip) {
    from "../../z_vr_assets/"
    destinationDir file("../../assets/")
    archiveName "z_vr_assets.pk3"
}

task packJAResources(type: Zip) {
    from "../../z_vr_assets_jka/"
    destinationDir file("../../assets/")
    archiveName "z_vr_assets_jka.pk3"
}

tasks.matching {it.name.startsWith("assemble")}.all { Task task ->
    task.dependsOn([packJOResources, packJAResources])
}
