tools-make/configure.in

AC_INIT(application.make)

#
#   configure.in
#
#   Copyright (C) 1997 Free Software Foundation, Inc.
#
#   Author:  Scott Christley <scottc@net-community.com>
#
#   This file is part of the GNUstep Makefile Package.
#
#   This library is free software; you can redistribute it and/or
#   modify it under the terms of the GNU General Public License
#   as published by the Free Software Foundation; either version 2
#   of the License, or (at your option) any later version.
#   
#   You should have received a copy of the GNU General Public
#   License along with this library; see the file COPYING.LIB.
#   If not, write to the Free Software Foundation,
#   59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

AC_CONFIG_HEADER(config.h)

#--------------------------------------------------------------------
# The GNUstep root directory.
# The user should have the GNUSTEP_SYSTEM_ROOT environment variable
# defined, but if not then we have a global default.
#--------------------------------------------------------------------
AC_PREFIX_DEFAULT(`if test "x$GNUSTEP_SYSTEM_ROOT" = "x"; then 
echo /usr/GNUstep ;
else
echo $GNUSTEP_SYSTEM_ROOT ;
fi`)

#--------------------------------------------------------------------
# Determine the host, build, and target systems
#--------------------------------------------------------------------
AC_CANONICAL_SYSTEM

#--------------------------------------------------------------------
# Find the binary and compile tools
#--------------------------------------------------------------------
AC_PROG_CC
AC_PROG_CPP
AC_PROG_RANLIB

AC_PROG_INSTALL
# HOST_INSTALL is the name of the install program in config.make so set it up
# to point to the install-sh script in the GNUstep tree if no system install is
# found.
AC_SUBST(HOST_INSTALL)
if test "$INSTALL" = "$ac_install_sh"; then
  HOST_INSTALL=$prefix/Makefiles/$INSTALL
else
  HOST_INSTALL=$INSTALL
fi

AC_LN_S

#--------------------------------------------------------------------
# Find for X windows
#--------------------------------------------------------------------
AC_PATH_X
X_INCLUDE=""
if test -n "$x_includes"; then
    X_INCLUDE="-I$x_includes"
fi
X_LIBS=""
if test -n "$x_libraries"; then
    X_LIBS="-L$x_libraries"
fi
if test -r $x_includes/X11/DPS; then
  X_INCLUDE="$X_INCLUDE -I$x_includes/X11"
fi

AC_SUBST(X_INCLUDE)
AC_SUBST(X_LIBS)

AC_HEADER_DIRENT
AC_HAVE_HEADERS(sys/param.h sys/file.h dir.h string.h stdlib.h sys/types.h dnl
		sys/stat.h sys/errno.h)

#--------------------------------------------------------------------
# Setup the library combination
#--------------------------------------------------------------------
AC_ARG_WITH(library-combo,[

--with-library-combo
    Define the default library combinations that will be used when you type
    'make'. You can still change the library combination at runtime by
    specifying the 'library_combo' make variable. For example:
    
      $ make library_combo=nx_pdo_nx_nil
],
ac_cv_library_combo=$withval,
ac_cv_library_combo=$withval
)

if test "$ac_cv_library_combo" = ""; then
  if test $host_os = nextstep4; then
    ac_cv_library_combo=nx_nx_nx_nil
  else
    ac_cv_library_combo=gnu_gnu_gnu_xdp
  fi
fi
AC_SUBST(ac_cv_library_combo)

#--------------------------------------------------------------------
# Produce the output files
#--------------------------------------------------------------------
AC_OUTPUT(config.h config.make openapp Makefile GNUstep.sh)