tools-make/GNUstep.csh.in

#!/bin/csh
#
#   GNUstep.csh.in
#
#   Shell initialization for the GNUstep environment.
#
#   Copyright (C) 1998 Free Software Foundation, Inc.
#
#   Author:  Scott Christley <scottc@net-community.com>
#
#   This file is part of the GNUstep Makefile Package.
#
#   This library is free software; you can redistribute it and/or
#   modify it under the terms of the GNU General Public License
#   as published by the Free Software Foundation; either version 2
#   of the License, or (at your option) any later version.
#   
#   You should have received a copy of the GNU General Public
#   License along with this library; see the file COPYING.LIB.
#   If not, write to the Free Software Foundation,
#   59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
#

#
# Set the GNUstep system root and local root
#
setenv GNUSTEP_ROOT @GNUSTEP_ROOT@
setenv GNUSTEP_SYSTEM_ROOT @prefix@
if ( ! ${?LIBRARY_COMBO} ) then
  setenv LIBRARY_COMBO @ac_cv_library_combo@
endif

setenv GNUSTEP_LOCAL_ROOT "${GNUSTEP_ROOT}/Local"
setenv GNUSTEP_NETWORK_ROOT 
setenv GNUSTEP_USER_ROOT ~/GNUstep

if ( ! ${?GNUSTEP_BUILD_ROOT} ) then
  setenv GNUSTEP_MAKEFILES ${GNUSTEP_SYSTEM_ROOT}/Makefiles
else
  setenv GNUSTEP_MAKEFILES ${GNUSTEP_BUILD_ROOT}/Makefiles
endif

#
# Determine the host information
#
if ( ! ${?GNUSTEP_HOST} ) then
  pushd /tmp > /dev/null
  setenv GNUSTEP_HOST `${GNUSTEP_SYSTEM_ROOT}/Makefiles/config.guess`
  setenv GNUSTEP_HOST `${GNUSTEP_SYSTEM_ROOT}/Makefiles/config.sub ${GNUSTEP_HOST}`
  popd > /dev/null
endif
setenv GNUSTEP_HOST_CPU `${GNUSTEP_SYSTEM_ROOT}/Makefiles/cpu.sh $GNUSTEP_HOST`
setenv GNUSTEP_HOST_VENDOR `${GNUSTEP_SYSTEM_ROOT}/Makefiles/vendor.sh $GNUSTEP_HOST`
setenv GNUSTEP_HOST_OS `${GNUSTEP_SYSTEM_ROOT}/Makefiles/os.sh $GNUSTEP_HOST`

# Clean the host
setenv GNUSTEP_HOST_CPU `${GNUSTEP_SYSTEM_ROOT}/Makefiles/clean_cpu.sh $GNUSTEP_HOST_CPU`
setenv GNUSTEP_HOST_VENDOR `${GNUSTEP_SYSTEM_ROOT}/Makefiles/clean_vendor.sh $GNUSTEP_HOST_VENDOR`
setenv GNUSTEP_HOST_OS `${GNUSTEP_SYSTEM_ROOT}/Makefiles/clean_os.sh $GNUSTEP_HOST_OS`

#
# the rest of this file is only executed, if the core already is installed.
#

if ( ! ${?GNUSTEP_BUILD_ROOT} ) then

#
# Add the GNUstep tools directories to the path
#
if ( ! ${?GNUSTEP_PATHPREFIX_LIST} ) then
  setenv GNUSTEP_PATHPREFIX_LIST ${GNUSTEP_USER_ROOT}:${GNUSTEP_LOCAL_ROOT}:${GNUSTEP_SYSTEM_ROOT}:${GNUSTEP_NETWORK_ROOT}
endif # ( "${GNUSTEP_PATHPREFIX_LIST}" == "" )

set tp = ""
foreach dir ( `/bin/sh -c 'IFS=:; for i in ${GNUSTEP_PATHPREFIX_LIST}; do echo $i; done'` )
  set tp=${tp}${dir}/Tools:
  set tp=${tp}${dir}/Tools/${GNUSTEP_HOST_CPU}/${GNUSTEP_HOST_OS}:
end
setenv PATH ${tp}${PATH}

if ( ! ${?MANPATH} ) then
  setenv MANPATH ${GNUSTEP_SYSTEM_ROOT}/Library/man:/usr/local/man:/usr/man
else
  setenv MANPATH ${GNUSTEP_SYSTEM_ROOT}/Library/man:${MANPATH}
endif

source ${GNUSTEP_SYSTEM_ROOT}/Makefiles/ld_lib_path.csh

#
# Perform any user initialization
#
if ( -e ~/.GNUstep/GNUstep.csh ) then
  . ~/.GNUstep/GNUstep.csh
endif

if ( -x ${GNUSTEP_SYSTEM_ROOT}/Tools/make_services ) then
  ${GNUSTEP_SYSTEM_ROOT}/Tools/make_services &
endif

endif # ( "${GNUSTEP_BUILD_ROOT}" == "" )

#
# Set the Java CLASSPATH  (i haven't tested this csh version yet)
#
if ( ! ${?CLASSPATH} ) then
  setenv MY_CLASSPATH .
else
  setenv MY_CLASSPATH ${CLASSPATH}:.
endif

setenv CLASSPATH ${GNUSTEP_SYSTEM_ROOT}/Java/:${GNUSTEP_USER_ROOT}/Java/:${GNUSTEP_LOCAL_ROOT}/Java/:${GNUSTEP_NETWORK_ROOT}/Java/:${MY_CLASSPATH}

unsetenv MY_CLASSPATH