cnq3/code/renderer/shaders/crp/prepass.hlsl

/*
===========================================================================
Copyright (C) 2024 Gian 'myT' Schellenbaum

This file is part of Challenge Quake 3 (CNQ3).

Challenge Quake 3 is free software; you can redistribute it
and/or modify it under the terms of the GNU General Public License as
published by the Free Software Foundation; either version 2 of the License,
or (at your option) any later version.

Challenge Quake 3 is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with Challenge Quake 3. If not, see <https://www.gnu.org/licenses/>.
===========================================================================
*/
// generic shader for the prepass of opaque surfaces


#include "common.hlsli"
#include "alpha_test.h.hlsli"
#include "scene_view.h.hlsli"


cbuffer RootConstants
{
	matrix modelViewMatrix;
	matrix modelMatrix;
	matrix normalMatrix;
	uint textureIndex;
	uint samplerIndex;
	uint alphaTest;
};

struct VIn
{
	float3 position : POSITION;
	float3 normal : NORMAL;
	float2 texCoords : TEXCOORD0;
	float4 color : COLOR0;
};

struct VOut
{
	float4 position : SV_Position;
	nointerpolation float3 normalWS : NORMAL;
	nointerpolation float3 positionWS : POSITION;
	float2 texCoords : TEXCOORD0;
	float4 color : COLOR0;
	float clipDist : SV_ClipDistance0;
};

VOut vs(VIn input)
{
	SceneView scene = GetSceneView();
	matrix projectionMatrix = scene.projectionMatrix;
	float4 positionVS = mul(modelViewMatrix, float4(input.position.xyz, 1));

	VOut output;
	output.position = mul(projectionMatrix, positionVS);
	output.normalWS = mul(normalMatrix, float4(input.normal, 0)).xyz;
	output.positionWS = mul(modelMatrix, float4(input.position, 1)).xyz;
	output.texCoords = input.texCoords;
	output.color = input.color;
	output.clipDist = dot(positionVS, scene.clipPlane);

	return output;
}

struct POut
{
	float2 normal : SV_Target0;
	float2 motionVector : SV_Target1;
	float4 shadingPosition : SV_Target2;
};

float3 FixNormal(float3 vertexNormal, float3 faceNormal)
{
	if(length(vertexNormal) < 0.5)
	{
		return faceNormal;
	}

	if(dot(vertexNormal, faceNormal) < 0.0)
	{
		return -vertexNormal;
	}

	return vertexNormal;
}

POut ps(VOut input, float3 barycentrics : SV_Barycentrics)
{
	if(alphaTest != ATEST_NONE)
	{
		Texture2D texture0 = ResourceDescriptorHeap[textureIndex];
		SamplerState sampler0 = ResourceDescriptorHeap[samplerIndex];
		float4 dst = texture0.Sample(sampler0, input.texCoords) * input.color;
		if(FailsAlphaTest(dst.a, alphaTest))
		{
			discard;
		}
	}

	float3 p0 = GetAttributeAtVertex(input.positionWS, 0);
	float3 p1 = GetAttributeAtVertex(input.positionWS, 1);
	float3 p2 = GetAttributeAtVertex(input.positionWS, 2);
	float3 position = barycentrics.x * p0 + barycentrics.y * p1 + barycentrics.z * p2;

	float3 n0 = GetAttributeAtVertex(input.normalWS, 0);
	float3 n1 = GetAttributeAtVertex(input.normalWS, 1);
	float3 n2 = GetAttributeAtVertex(input.normalWS, 2);
	float3 normal = barycentrics.x * n0 + barycentrics.y * n1 + barycentrics.z * n2;

	float3 pos[3] = { p0, p1, p2 };
	float3 nor[3] = { n0, n1, n2 };
	float3 shadingPosition = GetShadingPosition(position, normal, pos, nor, barycentrics);
	shadingPosition += 0.01 * normal;

	float3 dist3 = saturate(abs(shadingPosition - position));
	float dist = saturate(distance(shadingPosition, position));
	float positionDelta = asfloat(PackColor(float4(dist3, dist)));

	POut output;
	output.normal = OctEncode(normalize(normal));
	output.motionVector = float2(0, 0); // @TODO:
	output.shadingPosition = float4(shadingPosition, positionDelta);

	return output;
}