cnq3/code/renderer/shaders/crp/opaque.hlsl

/*
===========================================================================
Copyright (C) 2023 Gian 'myT' Schellenbaum

This file is part of Challenge Quake 3 (CNQ3).

Challenge Quake 3 is free software; you can redistribute it
and/or modify it under the terms of the GNU General Public License as
published by the Free Software Foundation; either version 2 of the License,
or (at your option) any later version.

Challenge Quake 3 is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with Challenge Quake 3. If not, see <https://www.gnu.org/licenses/>.
===========================================================================
*/
// generic shader for opaque surfaces


#include "common.hlsli"
#include "world.h.hlsli"
#include "world.hlsli"


cbuffer RootConstants
{
	// geometry
	matrix modelViewMatrix;
	matrix projectionMatrix;
	float4 clipPlane;

	// general
	uint textureIndex;
	uint samplerIndex;
	uint shaderIndexBufferIndex;
	uint alphaTest;
	float greyscale;

	// shader trace
	uint shaderTrace; // shader index: 14 - frame index: 2 - enable: 1
	uint centerPixel; // y: 16 - x: 16

	// @TODO: dither
	// @TODO: Voronoi tiling
};


#if VERTEX_SHADER

struct VIn
{
	float3 position : POSITION;
	float3 normal : NORMAL;
	float2 texCoords : TEXCOORD0;
	float4 color : COLOR0;
};

#endif

struct VOut
{
	float4 position : SV_Position;
	float3 normal : NORMAL;
	float2 texCoords : TEXCOORD0;
	float4 color : COLOR0;
	float clipDist : SV_ClipDistance0;
	float2 proj2232 : PROJ;
	float depthVS : DEPTHVS;
};


#if VERTEX_SHADER

VOut vs(VIn input)
{
	float4 positionVS = mul(modelViewMatrix, float4(input.position.xyz, 1));

	VOut output;
	output.position = mul(projectionMatrix, positionVS);
	output.normal = input.normal;
	output.texCoords = input.texCoords;
	output.color = input.color;
	output.clipDist = dot(positionVS, clipPlane);
	output.proj2232 = float2(-projectionMatrix[2][2], projectionMatrix[2][3]);
	output.depthVS = -positionVS.z;

	return output;
}

#endif


#if PIXEL_SHADER

float4 ps(VOut input) : SV_Target
{
	// @TODO: Voronoi tiling
	Texture2D texture0 = ResourceDescriptorHeap[textureIndex];
	SamplerState sampler0 = ResourceDescriptorHeap[samplerIndex];
	float4 dst = texture0.Sample(sampler0, input.texCoords) * input.color;
	if(FailsAlphaTest(dst.a, alphaTest))
	{
		discard;
	}

	dst = MakeGreyscale(dst, greyscale);

	// @TODO: dithering (need to figure out the tone mapping function first)

	if(shaderTrace & 1)
	{
		// we only store the shader index of 1 pixel
		uint2 fragmentCoords = uint2(input.position.xy);
		uint2 centerCoords = uint2(centerPixel & 0xFFFF, centerPixel >> 16);
		if(all(fragmentCoords == centerCoords))
		{
			RWByteAddressBuffer shaderIndexBuffer = ResourceDescriptorHeap[shaderIndexBufferIndex];
			uint frameIndex = (shaderTrace >> 1) & 3;
			uint shaderIndex = shaderTrace >> 3;
			shaderIndexBuffer.Store(frameIndex * 4, shaderIndex);
		}
	}

	return dst;
}

#endif